! Moving force across a single span beam, solved with ANSYS
!--------------------------------------------------------------------------
!--------------------------------------------------------------------------
! School of Mechanical and Manufacturing Engineering, University of New
! South Wales
! Author:   Gareth Forbes
! Date created: 13/8/08
! Date last modified: 13/8/08
! -------------------------------------------------------------------------
! -------------------------------------------------------------------------
! Description of Script: 
! Creates the response of a single span beam under the influence of a
! moving force, for use with the ANSYS FEA software. More information can 
! be found at www.varg.unsw.edu.au/movingload
!
!
! -------------------------------------------------------------------------
! -------------------------------------------------------------------------
! beam with 11 nodes consecutively numbered
! note script only works for a 10 element simply supported beam

/PREP7  
ET,1,BEAM3  
R,1,10,10000/12,10, , , ,  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200000 
MPDATA,PRXY,1,,0.3  
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,DENS,1,,7.8E-9  
mat,1
type,1
real,1 
*DO,i,1,11,1
N,i,(i-1)*100,0,0
*ENDDO
*DO,i,1,10,1
EN,i,i,i+1
*ENDDO

FINISH


! define beam length in mm
Lt = 1000
!number of elements
EL = 10
! number of nodes
N = EL + 1
! forceing function in newtons, single pont force
P = -100
!speed of moving load mm/s
V = 10000
! manual time step
tstepm = 1000
! all elements are defined as having the same length therefore the element
! lenght is
L = Lt/EL
ttotal = Lt/V
deltat1 = L/V
deltat = min((1/(1/deltat1+1)),ttotal/tstepm)
tstep = max(NINT(ttotal/deltat),tstepm)
 
/CONFIG,NRES,tstep
/SOL
ANTYPE,4 
TRNOPT,FULL 
LUMPM,0 
ALPHAD,0  
BETAD,0.0005

D,1, ,0, , , ,UX,UY, , , ,
D,11, ,0, , , ,UX,UY, , , ,

TM_START=deltat               ! Starting time (must be > 0)
TM_END=ttotal                  ! Ending time of the transient
TM_INCR=deltat                 ! Time increment
nnode=11			!number of nodes

*DO,TM,TM_START,TM_END,TM_INCR    ! Do for TM from TM_START to TM_END in
                                  !  steps of TM_INCR
   TIME,TM                  ! Time value
	*DO,i,1,nnode,1
		xp = V*TM
		ff = (xp/L+1)/NINT(xp/L+1)
		*IF,ff,GE,1,THEN
			s1 = NINT(xp/L)
		*ELSE
			s1 = NINT(xp/L)-1
		*ENDIF
		s = s1+1 
        	zeta = (xp - (s-1)*L)/(L)
        	N1 = 1 - 3*zeta**2 + 2*zeta**3
        	N2 = (zeta - 2*zeta**2 + zeta**3)*L
        	N3 = 3*zeta**2 - 2*zeta**3
        	N4 = (-zeta**2 + zeta**3)*L
            	*IF,i,EQ,s,THEN
                	Fy11 = P*N1
            	*ELSEIF,i,EQ,s+1
                	Fy11 = P*N3
            	*ELSE
                	Fy11 = 0
            	*ENDIF
            	*IF,i,EQ,s,THEN 
                	Mz11 = P*N2
            	*ELSEIF,i,EQ,s+1
                	Mz11 = P*N4
            	*ELSE
                	Mz11 = 0
            	*ENDIF

		F,i,FY,Fy11
		F,i,MZ,Mz11
		
   	*ENDDO
   SOLVE                    ! Initiate solution calculations
*ENDDO